vkill'blog

@echo off
title IP地址地理位置^/手机号码归属地查询(网络版)  by:vkill
::需要外部工具 curl.exe & sed.exe ,下载:http://www.vkill.net/tools.html ,用的是ip138的数据库
:start_
cls&set v=&set a=
set/p=你输入你要查询的IP地址或手机号码:<nul & set/p "v="
if not defined v goto :start_
echo 正在查询,请稍候......
echo.
echo "%v%"|find ".">nul 2>nul &&(
echo 您查询的IP:%v%
for /f "tokens=*" %%? in ('curl -s -d "ip=%v%&action=ip" http://ip138.com/ips8.asp^|sed "/本站主数据：/!d;s/<li>/\n/g;s/<[^>]*>//g;s/^[ \t]*//g"') do (echo %%?)
                                 )||(
echo 您查询的手机号码段:%v%
for /f "tokens=*" %%? in ('curl -s -d "mobile=%v%&action=mobile" http://www.ip138.com:8080/search.asp^|sed "s/ //g"^|sed -r -n "/卡号归属地|卡类型/{n;p}"^|sed "s/<[^>]*>//g;s/^[ \t]*//g"') do (
 if not defined a (
 echo 卡号归属地:%%?
 set a=a) else (echo 卡  类  型:%%?)
                                       )
)
echo.
set/p=任意键继续......<nul&pause>nul&goto :start_

@echo off
title 手机号码归属地查询(单机版)  by:namejm
mode con lines=10 cols=31
:Main
cls
echo.&echo.
echo        请输入手机号码：
echo.
set input=
set /p input=        
if not defined input exit    
if "%input:~10%"=="" goto Main
if not "%input:~11%"=="" goto Main
echo %input%|findstr "^1[3,5][0-9]*$">nul||goto Main
cls
echo.
set ID=%input:~0,7%
for /f "tokens=2,4,6,8,10 delims='" %%i in ('findstr /r "%ID%" 手机信息数据库.txt') do (
   echo ━━━━━━━━━━━━━━━
   echo   来自： %%k %%l
   echo.
   echo   品牌：%%m
   echo.
   echo   电话区号：%%j
   echo ━━━━━━━━━━━━━━━
)
pause>nul
goto Main